Weather_WH2.ino

   1 /*
   2   Updated code for receiving data from WH2 weather station
   3   This code implements timeouts to make decoding more robust
   4   Decodes received packets and writes a summary of each packet to the Arduino's
   5   serial port
   6   Created by Luc Small on 19 July 2013.
   7   Released into the public domain.
   8 */
   9
  10 #include <dht.h>
  11 #include <Wire.h>
  12 #include <BMP085.h>
  13
  14 // DHT11 and BMP085 wired sensors
  15 dht DHT;
  16 BMP085 bmp;
  17
  18 // Humidity sensor at pin 4
  19 #define DHT11PIN 5
  20
  21 #define DEBUG
  22
  23 // LED pins
  24 #define REDPIN 11
  25 #define GREENPIN 12
  26
  27 // Read data from 433MHz receiver on digital pin 3
  28 #define RF_IN 4
  29 // For better efficiency, the port is read directly
  30 // the following two lines should be changed appropriately
  31 // if the line above is changed.
  32 #define RF_IN_RAW PIND4
  33 #define RF_IN_PIN PIND
  34
  35 // Port that is hooked to LED to indicate a packet has been received
  36
  37 #define COUNTER_RATE 3200-1 // 16,000,000Hz / 3200 = 5000 interrupts per second, ie. 200us between interrupts
  38 // 1 is indicated by 500uS pulse
  39 // wh2_accept from 2 = 400us to 3 = 600us
  40 #define IS_HI_PULSE(interval)   (interval >= 2 && interval <= 3)
  41 // 0 is indicated by ~1500us pulse
  42 // wh2_accept from 7 = 1400us to 8 = 1600us
  43 #define IS_LOW_PULSE(interval)  (interval >= 7 && interval <= 8)
  44 // worst case packet length
  45 // 6 bytes x 8 bits x (1.5 + 1) = 120ms; 120ms = 200us x 600
  46 #define HAS_TIMED_OUT(interval) (interval > 600)
  47 // we expect 1ms of idle time between pulses
  48 // so if our pulse hasn't arrived by 1.2ms, reset the wh2_packet_state machine
  49 // 6 x 200us = 1.2ms
  50 #define IDLE_HAS_TIMED_OUT(interval) (interval > 6)
  51 // our expected pulse should arrive after 1ms
  52 // we'll wh2_accept it if it arrives after
  53 // 4 x 200us = 800us
  54 #define IDLE_PERIOD_DONE(interval) (interval >= 4)
  55 // Shorthand for tests
  56 //#define RF_HI (digitalRead(RF_IN) == HIGH)
  57 //#define RF_LOW (digitalRead(RF_IN) == LOW)
  58 #define RF_HI (bit_is_set(RF_IN_PIN, RF_IN_RAW))
  59 #define RF_LOW (bit_is_clear(RF_IN_PIN, RF_IN_RAW))
  60
  61 // wh2_flags
  62 #define GOT_PULSE 0x01
  63 #define LOGIC_HI  0x02
  64 volatile byte wh2_flags = 0;
  65 volatile byte wh2_packet_state = 0;
  66 volatile int wh2_timeout = 0;
  67 byte wh2_packet[5];
  68 byte wh2_calculated_crc;
  69
  70
  71 #ifdef DEBUG
  72 byte printed = 0;
  73 #endif
  74
  75 ISR(TIMER1_COMPA_vect)
  76 {
  77   static byte sampling_state = 0;
  78   static byte count;
  79   static boolean was_low = false;
  80
  81   switch(sampling_state) {
  82     case 0: // waiting
  83       wh2_packet_state = 0;
  84       if (RF_HI) {
  85         if (was_low) {
  86           count = 0;
  87           sampling_state = 1;
  88           was_low = false;
  89         }
  90       } else {
  91         was_low = true;
  92       }
  93       break;
  94     case 1: // acquiring first pulse
  95       count++;
  96       // end of first pulse
  97       if (RF_LOW) {
  98         if (IS_HI_PULSE(count)) {
  99           wh2_flags = GOT_PULSE | LOGIC_HI;
 100           sampling_state = 2;
 101           count = 0;
 102         } else if (IS_LOW_PULSE(count)) {
 103           wh2_flags = GOT_PULSE; // logic low
 104           sampling_state = 2;
 105           count = 0;
 106         } else {
 107           sampling_state = 0;
 108         }
 109       }
 110       break;
 111     case 2: // observe 1ms of idle time
 112       count++;
 113       if (RF_HI) {
 114          if (IDLE_HAS_TIMED_OUT(count)) {
 115            sampling_state = 0;
 116          } else if (IDLE_PERIOD_DONE(count)) {
 117            sampling_state = 1;
 118            count = 0;
 119          }
 120       }
 121       break;
 122   }
 123
 124   if (wh2_timeout > 0) {
 125     wh2_timeout++;
 126     if (HAS_TIMED_OUT(wh2_timeout)) {
 127       wh2_packet_state = 0;
 128       wh2_timeout = 0;
 129 #ifdef DEBUG
 130       if (printed) {
 131         Serial1.println();
 132         printed=0;
 133       }
 134 #endif
 135     }
 136   }
 137 }
 138
 139 void setup() {
 140
 141   Serial1.begin(57600);
 142   Serial1.println();
 143   Serial1.println("STATUS:STARTING");
 144
 145   bmp.begin();
 146
 147   pinMode(REDPIN,OUTPUT);
 148   pinMode(GREENPIN,OUTPUT);
 149
 150   pinMode(RF_IN, INPUT);
 151   digitalWrite(RF_IN,HIGH);
 152
 153   TCCR1A = 0x00;
 154   TCCR1B = 0x09;
 155   TCCR1C = 0x00;
 156   OCR1A = COUNTER_RATE;
 157   TIMSK1 = 0x02;
 158
 159   // enable interrupts
 160   sei();
 161 }
 162
 163 unsigned long previousMillis = 0;
 164 unsigned long indoor_interval = 60000;
 165 unsigned long outdoor_interval = 45000;
 166 unsigned long previousIndoor = 0;
 167 unsigned long previousOutdoor = 0;
 168
 169
 170 void loop() {
 171   unsigned long now;
 172   byte i;
 173
 174   now = millis();
 175
 176   if (wh2_flags) {
 177     if (wh2_accept()) {
 178       // calculate the CRC
 179       wh2_calculate_crc();
 180
 181       if (wh2_valid()) {
 182
 183         Serial1.println();
 184         Serial1.print("SENSOR:TYPE=OUTDOOR,");
 185
 186         Serial1.print("ID=");
 187         Serial1.print(wh2_sensor_id(), HEX);
 188
 189         Serial1.print(",HUMIDITY=");
 190         Serial1.print(wh2_humidity(), DEC);
 191
 192         Serial1.print(",TEMPERATURE=");
 193         Serial1.println(format_temp(wh2_temperature()));
 194
 195         previousOutdoor = now;
 196         digitalWrite(REDPIN,HIGH);
 197
 198       } else {
 199
 200         Serial1.println();
 201         Serial1.println("ERROR:OUTDOOR");
 202         previousOutdoor = now;
 203         digitalWrite(REDPIN,LOW);
 204
 205       }
 206
 207    }
 208    wh2_flags = 0x00;
 209   }
 210
 211   if ((unsigned long)(now - previousMillis) >= indoor_interval) {
 212
 213     previousMillis = now;
 214
 215     int chk = DHT.read11(DHT11PIN);
 216
 217     if (chk==0) {
 218
 219       Serial1.println();
 220       Serial1.print("SENSOR:TYPE=INDOOR,");
 221       Serial1.print("HUMIDITY=");
 222       Serial1.print(DHT.humidity);
 223       Serial1.print(",TEMPERATURE=");
 224       Serial1.print(DHT.temperature);
 225
 226       Serial1.println();
 227       Serial1.print("SENSOR:TYPE=BARO,");
 228       Serial1.print("PRESSURE=");
 229       Serial1.print(bmp.readPressure());
 230       Serial1.print(",TEMPERATURE=");
 231       Serial1.println(bmp.readTemperature());
 232
 233       previousIndoor = now;
 234       digitalWrite(GREENPIN,HIGH);
 235
 236
 237     } else {
 238
 239       Serial1.println();
 240       Serial1.println("ERROR:INDOOR");
 241       previousIndoor = now;
 242       digitalWrite(GREENPIN,LOW);
 243
 244     }
 245
 246   }
 247
 248   if ((unsigned long)(now - previousIndoor) > indoor_interval*10) {
 249
 250       Serial1.println();
 251       Serial1.println("ERROR:INDOOR TIMEOUT");
 252       previousIndoor = now;
 253       digitalWrite(GREENPIN,LOW);
 254
 255   }
 256
 257   if ((unsigned long)(now - previousOutdoor) > outdoor_interval*10) {
 258
 259       Serial1.println();
 260       Serial1.println("ERROR:OUTDOOR TIMEOUT");
 261       previousOutdoor = now;
 262       digitalWrite(REDPIN,LOW);
 263
 264   }
 265
 266
 267 }
 268
 269
 270 // processes new pulse
 271 boolean wh2_accept()
 272 {
 273   static byte packet_no, bit_no, history;
 274
 275   // reset if in initial wh2_packet_state
 276   if(wh2_packet_state == 0) {
 277      // should history be 0, does it matter?
 278     history = 0xFF;
 279     wh2_packet_state = 1;
 280     // enable wh2_timeout
 281     wh2_timeout = 1;
 282   } // fall thru to wh2_packet_state one
 283
 284   // acquire preamble
 285   if (wh2_packet_state == 1) {
 286      // shift history right and store new value
 287      history <<= 1;
 288      // store a 1 if required (right shift along will store a 0)
 289      if (wh2_flags & LOGIC_HI) {
 290        history |= 0x01;
 291      }
 292      // check if we have a valid start of frame
 293      // xxxxx110
 294      if ((history & B00000111) == B00000110) {
 295        // need to clear packet, and counters
 296        packet_no = 0;
 297        // start at 1 becuase only need to acquire 7 bits for first packet byte.
 298        bit_no = 1;
 299        wh2_packet[0] = wh2_packet[1] = wh2_packet[2] = wh2_packet[3] = wh2_packet[4] = 0;
 300        // we've acquired the preamble
 301        wh2_packet_state = 2;
 302     }
 303     return false;
 304   }
 305   // acquire packet
 306   if (wh2_packet_state == 2) {
 307
 308     wh2_packet[packet_no] <<= 1;
 309     if (wh2_flags & LOGIC_HI) {
 310       wh2_packet[packet_no] |= 0x01;
 311 #ifdef DEBUG
 312       Serial1.print('1');
 313       printed=1;
 314     } else {
 315       Serial1.print('0');
 316       printed=1;
 317 #endif
 318     }
 319
 320     bit_no ++;
 321     if(bit_no > 7) {
 322       bit_no = 0;
 323       packet_no ++;
 324     }
 325
 326     if (packet_no > 4) {
 327       // start the sampling process from scratch
 328       wh2_packet_state = 0;
 329       // clear wh2_timeout
 330       wh2_timeout = 0;
 331       return true;
 332     }
 333   }
 334   return false;
 335 }
 336
 337
 338 void wh2_calculate_crc()
 339 {
 340   wh2_calculated_crc = crc8(wh2_packet, 4);
 341 }
 342
 343 bool wh2_valid()
 344 {
 345   return (wh2_calculated_crc == wh2_packet[4]);
 346 }
 347
 348 int wh2_sensor_id()
 349 {
 350   return (wh2_packet[0] << 4) + (wh2_packet[1] >> 4);
 351 }
 352
 353 byte wh2_humidity()
 354 {
 355   return wh2_packet[3];
 356 }
 357
 358 /* Temperature in deci-degrees. e.g. 251 = 25.1 */
 359 int wh2_temperature()
 360 {
 361   int temperature;
 362   temperature = ((wh2_packet[1] & B00000111) << 8) + wh2_packet[2];
 363   // make negative
 364   if (wh2_packet[1] & B00001000) {
 365     temperature = -temperature;
 366   }
 367   return temperature;
 368 }
 369
 370 String format_temp(int temperature)
 371 {
 372   byte whole, partial;
 373   String s;
 374   s = String();
 375   if (temperature<0) {
 376     temperature = -temperature;
 377     s += String('-');
 378   }
 379
 380   whole = temperature / 10;
 381   partial = temperature - (whole*10);
 382
 383   s += String(whole, DEC);
 384   s += '.';
 385   s += String(partial, DEC);
 386
 387   return s;
 388
 389 }
 390
 391 uint8_t crc8( uint8_t *addr, uint8_t len)
 392 {
 393   uint8_t crc = 0;
 394
 395   // Indicated changes are from reference CRC-8 function in OneWire library
 396   while (len--) {
 397     uint8_t inbyte = *addr++;
 398     for (uint8_t i = 8; i; i--) {
 399       uint8_t mix = (crc ^ inbyte) & 0x80; // changed from & 0x01
 400       crc <<= 1; // changed from right shift
 401       if (mix) crc ^= 0x31;// changed from 0x8C;
 402       inbyte <<= 1; // changed from right shift
 403     }
 404   }
 405   return crc;
 406 }
 407
 408
 409
 410
 411
 412
 413
 414
 415