Weather_WH2.ino

   1 /*
   2   Updated code for receiving data from WH2 weather station
   3   This code implements timeouts to make decoding more robust
   4   Decodes received packets and writes a summary of each packet to the Arduino's
   5   serial port
   6   Created by Luc Small on 19 July 2013.
   7   Released into the public domain.
   8 */
   9
  10 #include <dht.h>
  11 #include <Wire.h>
  12 #include <BMP085.h>
  13
  14 // DHT11 and BMP085 wired sensors
  15 dht DHT;
  16 BMP085 bmp;
  17
  18 // Humidity sensor at pin 4
  19 #define DHT11PIN 5
  20
  21 #define DEBUG
  22
  23 // LED pins
  24 #define REDPIN 11
  25 #define GREENPIN 12
  26
  27 // Read data from 433MHz receiver on digital pin 3
  28 #define RF_IN 4
  29 // For better efficiency, the port is read directly
  30 // the following two lines should be changed appropriately
  31 // if the line above is changed.
  32 #define RF_IN_RAW PIND4
  33 #define RF_IN_PIN PIND
  34
  35 // Port that is hooked to LED to indicate a packet has been received
  36
  37 #define COUNTER_RATE 3200-1 // 16,000,000Hz / 3200 = 5000 interrupts per second, ie. 200us between interrupts
  38 // 1 is indicated by 500uS pulse
  39 // wh2_accept from 2 = 400us to 3 = 600us
  40 #define IS_HI_PULSE(interval)   (interval >= 2 && interval <= 3)
  41 // 0 is indicated by ~1500us pulse
  42 // wh2_accept from 7 = 1400us to 8 = 1600us
  43 #define IS_LOW_PULSE(interval)  (interval >= 7 && interval <= 8)
  44 // worst case packet length
  45 // 6 bytes x 8 bits x (1.5 + 1) = 120ms; 120ms = 200us x 600
  46 #define HAS_TIMED_OUT(interval) (interval > 600)
  47 // we expect 1ms of idle time between pulses
  48 // so if our pulse hasn't arrived by 1.2ms, reset the wh2_packet_state machine
  49 // 6 x 200us = 1.2ms
  50 #define IDLE_HAS_TIMED_OUT(interval) (interval > 6)
  51 // our expected pulse should arrive after 1ms
  52 // we'll wh2_accept it if it arrives after
  53 // 4 x 200us = 800us
  54 #define IDLE_PERIOD_DONE(interval) (interval >= 4)
  55 // Shorthand for tests
  56 //#define RF_HI (digitalRead(RF_IN) == HIGH)
  57 //#define RF_LOW (digitalRead(RF_IN) == LOW)
  58 #define RF_HI (bit_is_set(RF_IN_PIN, RF_IN_RAW))
  59 #define RF_LOW (bit_is_clear(RF_IN_PIN, RF_IN_RAW))
  60
  61 // wh2_flags
  62 #define GOT_PULSE 0x01
  63 #define LOGIC_HI  0x02
  64 volatile byte wh2_flags = 0;
  65 volatile byte wh2_packet_state = 0;
  66 volatile int wh2_timeout = 0;
  67 byte wh2_packet[5];
  68 byte wh2_calculated_crc;
  69
  70
  71 #ifdef DEBUG
  72 byte printed = 0;
  73 #endif
  74
  75 ISR(TIMER1_COMPA_vect)
  76 {
  77   static byte sampling_state = 0;
  78   static byte count;
  79   static boolean was_low = false;
  80
  81   switch(sampling_state) {
  82     case 0: // waiting
  83       wh2_packet_state = 0;
  84       if (RF_HI) {
  85         if (was_low) {
  86           count = 0;
  87           sampling_state = 1;
  88           was_low = false;
  89         }
  90       } else {
  91         was_low = true;
  92       }
  93       break;
  94     case 1: // acquiring first pulse
  95       count++;
  96       // end of first pulse
  97       if (RF_LOW) {
  98         if (IS_HI_PULSE(count)) {
  99           wh2_flags = GOT_PULSE | LOGIC_HI;
 100           sampling_state = 2;
 101           count = 0;
 102         } else if (IS_LOW_PULSE(count)) {
 103           wh2_flags = GOT_PULSE; // logic low
 104           sampling_state = 2;
 105           count = 0;
 106         } else {
 107           sampling_state = 0;
 108         }
 109       }
 110       break;
 111     case 2: // observe 1ms of idle time
 112       count++;
 113       if (RF_HI) {
 114          if (IDLE_HAS_TIMED_OUT(count)) {
 115            sampling_state = 0;
 116          } else if (IDLE_PERIOD_DONE(count)) {
 117            sampling_state = 1;
 118            count = 0;
 119          }
 120       }
 121       break;
 122   }
 123
 124   if (wh2_timeout > 0) {
 125     wh2_timeout++;
 126     if (HAS_TIMED_OUT(wh2_timeout)) {
 127       wh2_packet_state = 0;
 128       wh2_timeout = 0;
 129 #ifdef DEBUG
 130       if (printed) {
 131         Serial1.println();
 132         printed=0;
 133       }
 134 #endif
 135     }
 136   }
 137 }
 138
 139 void setup() {
 140
 141   Serial1.begin(57600);
 142   Serial1.println();
 143   Serial1.println("STATUS:STARTING");
 144
 145   bmp.begin();
 146
 147   pinMode(REDPIN,OUTPUT);
 148   pinMode(GREENPIN,OUTPUT);
 149
 150   pinMode(RF_IN, INPUT);
 151   digitalWrite(RF_IN,HIGH);
 152
 153   TCCR1A = 0x00;
 154   TCCR1B = 0x09;
 155   TCCR1C = 0x00;
 156   OCR1A = COUNTER_RATE;
 157   TIMSK1 = 0x02;
 158
 159   // enable interrupts
 160   sei();
 161 }
 162
 163 unsigned long previousMillis = 0;
 164 unsigned long indoor_interval = 60000;
 165 unsigned long outdoor_interval = 45000;
 166 unsigned long previousIndoor = 0;
 167 unsigned long previousOutdoor = 0;
 168
 169
 170 void loop() {
 171   unsigned long now;
 172   byte i;
 173
 174   now = millis();
 175
 176   if (wh2_flags) {
 177     if (wh2_accept()) {
 178       // calculate the CRC
 179       wh2_calculate_crc();
 180
 181       if (wh2_valid()) {
 182
 183         Serial1.println();
 184         Serial1.print("SENSOR:TYPE=OUTDOOR,");
 185
 186         Serial1.print("ID=");
 187         Serial1.print(wh2_sensor_id(), HEX);
 188
 189         Serial1.print(",HUMIDITY=");
 190         Serial1.print(wh2_humidity(), DEC);
 191
 192         Serial1.print(",TEMPERATURE=");
 193         Serial1.println(format_temp(wh2_temperature()));
 194
 195         previousOutdoor = now;
 196         digitalWrite(REDPIN,HIGH);
 197
 198       } else {
 199
 200         Serial1.println();
 201         Serial1.println("ERROR:OUTDOOR");
 202         previousOutdoor = now;
 203         digitalWrite(REDPIN,LOW);
 204
 205       }
 206
 207    }
 208    wh2_flags = 0x00;
 209   }
 210
 211   if ((unsigned long)(now - previousMillis) >= indoor_interval) {
 212
 213     previousMillis = now;
 214
 215     int chk = DHT.read11(DHT11PIN);
 216
 217     if (chk==0) {
 218
 219       Serial1.println();
 220       Serial1.print("SENSOR:TYPE=INDOOR,");
 221       Serial1.print("HUMIDITY=");
 222       Serial1.print(DHT.humidity);
 223       Serial1.print(",TEMPERATURE=");
 224       Serial1.print(DHT.temperature);
 225
 226       Serial1.println();
 227       Serial1.print("SENSOR:TYPE=BARO,");
 228       Serial1.print("PRESSURE=");
 229       Serial1.print(bmp.readPressure());
 230       Serial1.print(",TEMPERATURE=");
 231       Serial1.println(bmp.readTemperature());
 232
 233       previousIndoor = now;
 234       digitalWrite(GREENPIN,HIGH);
 235
 236     } else {
 237
 238       Serial1.println();
 239       Serial1.println("ERROR:INDOOR");
 240       previousIndoor = now;
 241       digitalWrite(GREENPIN,LOW);
 242
 243     }
 244
 245   }
 246
 247   if ((unsigned long)(now - previousIndoor) > indoor_interval*10) {
 248
 249       Serial1.println();
 250       Serial1.println("ERROR:INDOOR TIMEOUT");
 251       previousIndoor = now;
 252       digitalWrite(GREENPIN,LOW);
 253
 254   }
 255
 256   if ((unsigned long)(now - previousOutdoor) > outdoor_interval*10) {
 257
 258       Serial1.println();
 259       Serial1.println("ERROR:OUTDOOR TIMEOUT");
 260       previousOutdoor = now;
 261       digitalWrite(REDPIN,LOW);
 262
 263   }
 264
 265 }
 266
 267
 268 // processes new pulse
 269 boolean wh2_accept()
 270 {
 271   static byte packet_no, bit_no, history;
 272
 273   // reset if in initial wh2_packet_state
 274   if(wh2_packet_state == 0) {
 275      // should history be 0, does it matter?
 276     history = 0xFF;
 277     wh2_packet_state = 1;
 278     // enable wh2_timeout
 279     wh2_timeout = 1;
 280   } // fall thru to wh2_packet_state one
 281
 282   // acquire preamble
 283   if (wh2_packet_state == 1) {
 284      // shift history right and store new value
 285      history <<= 1;
 286      // store a 1 if required (right shift along will store a 0)
 287      if (wh2_flags & LOGIC_HI) {
 288        history |= 0x01;
 289      }
 290      // check if we have a valid start of frame
 291      // xxxxx110
 292      if ((history & B00000111) == B00000110) {
 293        // need to clear packet, and counters
 294        packet_no = 0;
 295        // start at 1 becuase only need to acquire 7 bits for first packet byte.
 296        bit_no = 1;
 297        wh2_packet[0] = wh2_packet[1] = wh2_packet[2] = wh2_packet[3] = wh2_packet[4] = 0;
 298        // we've acquired the preamble
 299        wh2_packet_state = 2;
 300     }
 301     return false;
 302   }
 303   // acquire packet
 304   if (wh2_packet_state == 2) {
 305
 306     wh2_packet[packet_no] <<= 1;
 307     if (wh2_flags & LOGIC_HI) {
 308       wh2_packet[packet_no] |= 0x01;
 309 #ifdef DEBUG
 310       Serial1.print('1');
 311       printed=1;
 312     } else {
 313       Serial1.print('0');
 314       printed=1;
 315 #endif
 316     }
 317
 318     bit_no ++;
 319     if(bit_no > 7) {
 320       bit_no = 0;
 321       packet_no ++;
 322     }
 323
 324     if (packet_no > 4) {
 325       // start the sampling process from scratch
 326       wh2_packet_state = 0;
 327       // clear wh2_timeout
 328       wh2_timeout = 0;
 329       return true;
 330     }
 331   }
 332   return false;
 333 }
 334
 335
 336 void wh2_calculate_crc()
 337 {
 338   wh2_calculated_crc = crc8(wh2_packet, 4);
 339 }
 340
 341 bool wh2_valid()
 342 {
 343   return (wh2_calculated_crc == wh2_packet[4]);
 344 }
 345
 346 int wh2_sensor_id()
 347 {
 348   return (wh2_packet[0] << 4) + (wh2_packet[1] >> 4);
 349 }
 350
 351 byte wh2_humidity()
 352 {
 353   return wh2_packet[3];
 354 }
 355
 356 /* Temperature in deci-degrees. e.g. 251 = 25.1 */
 357 int wh2_temperature()
 358 {
 359   int temperature;
 360   temperature = ((wh2_packet[1] & B00000111) << 8) + wh2_packet[2];
 361   // make negative
 362   if (wh2_packet[1] & B00001000) {
 363     temperature = -temperature;
 364   }
 365   return temperature;
 366 }
 367
 368 String format_temp(int temperature)
 369 {
 370   byte whole, partial;
 371   String s;
 372   s = String();
 373   if (temperature<0) {
 374     temperature = -temperature;
 375     s += String('-');
 376   }
 377
 378   whole = temperature / 10;
 379   partial = temperature - (whole*10);
 380
 381   s += String(whole, DEC);
 382   s += '.';
 383   s += String(partial, DEC);
 384
 385   return s;
 386
 387 }
 388
 389 uint8_t crc8( uint8_t *addr, uint8_t len)
 390 {
 391   uint8_t crc = 0;
 392
 393   // Indicated changes are from reference CRC-8 function in OneWire library
 394   while (len--) {
 395     uint8_t inbyte = *addr++;
 396     for (uint8_t i = 8; i; i--) {
 397       uint8_t mix = (crc ^ inbyte) & 0x80; // changed from & 0x01
 398       crc <<= 1; // changed from right shift
 399       if (mix) crc ^= 0x31;// changed from 0x8C;
 400       inbyte <<= 1; // changed from right shift
 401     }
 402   }
 403   return crc;
 404 }
 405
 406
 407
 408
 409
 410
 411
 412
 413